home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1989 …il & Dave's Excellent CD / Excellent CD HFS.raw / Moof / Goodies / DTS Goodies / Hardware Hints / Examples / Example Vid ROM from C&D / C & D Ex Drvr.a next >
Encoding:
Text File  |  1988-05-24  |  14.1 KB  |  434 lines  |  [TEXT/MPS ]
  1. ;-----------------------------------------------------------------
  2.  
  3. ;General directives
  4.  
  5.             BLANKS        ON
  6.             STRING        ASIS
  7.  
  8.             
  9. ;=====================================================================
  10. ;    Local Vars, definitions, etc....
  11. ;=====================================================================
  12.  
  13. ; This is device storage which is stored in the dCtlStorage field of the DCE.
  14.  
  15. DCEPtr            EQU        0                        ; pointer to our DCE
  16. saveMode        EQU        DCEPtr+4                ; the current mode setting
  17. savePage        EQU        saveMode+2                ; the current page setting
  18. saveBaseAddr     EQU        savePage+2                ; the current base address
  19. saveSQElPtr     EQU        saveBaseAddr+4            ; the SQ element pointer (for _SIntRemove).
  20. GammaPtr         EQU        saveSQElPtr+4            ; the pointer to the Gamma correction table
  21. GFlags            EQU        GammaPtr+4                ; flags word
  22. VRAM256K        EQU        GFlags+2                ; boolean - TRUE if 256K vidRAM, FALSE if 512K
  23. dCtlSize        EQU        VRAM256K+2                ; size of dCtlStorage
  24.  
  25. ; Flags within GFlags word
  26.  
  27. GrayFlag        EQU        15                        ; luminance mapped if GFlags(GrayFlag) = 1
  28. TFB1K            EQU        0
  29.  
  30. ;=====================================================================
  31. ;    Video Driver Header
  32. ;=====================================================================
  33.             
  34. VidDrvr        DC.W    $4C00                    ; ctl,status,needsLock
  35.             DC.W    0,0,0                    ; not an ornament
  36.  
  37. ; Entry point offset table
  38.  
  39.             DC.W    VideoOpen-VidDrvr         ; open routine
  40.             DC.W    VidDrvr-VidDrvr            ; no prime
  41.             DC.W    VideoCtl-VidDrvr        ; control
  42.             DC.W    VideoStatus-VidDrvr        ; status
  43.             DC.W    VideoClose-VidDrvr        ; close
  44.  
  45.  
  46.             STRING        Pascal
  47. VideoTitle    DC.B        '.Display_Video_Apple_TFB'    ;
  48.             STRING        ASIS
  49.             ALIGN    2                        ; make sure we're aligned
  50.             DC.W    0                        ; version-0
  51.  
  52. ; 
  53. **********************************************************************
  54. *
  55. * VideoOpen allocates private storage for the device in the DCE and locks
  56. *    it down for perpituity. Also, install the interrupt handler and enable
  57. *    the interrupts.                                                                                                                 <22Sep86>
  58. *   It also sets the default gamma table included in the driver                        
  59. *
  60. * Entry:    A0 = param block pointer
  61. *            A1 = DCE pointer
  62. *
  63. * Locals:    A2 = Saved param block pointer
  64. *            A3 = Saved DCE pointer
  65. *            A4 = Saved interrupt handler ptr.
  66. *
  67. **********************************************************************
  68.  
  69. ; Save registers
  70. VideoOpen    MOVE.L    A0,A2                        ;A2 <- param block pointer
  71.             MOVE.L    A1,A3                        ;A3 <- DCE pointer
  72.             
  73. ; Allocate private storage.
  74.             MOVEQ    #dCtlSize,D0                ; get size of parameters
  75.             _ResrvMem  ,SYS                     ; make room as low as possible
  76.             MOVEQ    #dCtlSize,D0                ; get size of parameters
  77.             _NewHandle ,SYS,CLEAR                ; get some memory for private storage
  78.             BNE      OpError                        ; => return an error in open
  79.             MOVE.L    A0,dCtlStorage(A3)            ; save returned handle in DCE
  80.             _HLock                                ; and lock it down
  81.             
  82. ; Get and install the interrupt handler.                                        
  83.             LEA        BeginIH,A4                    ;Save Pointer to interrupt handler.    
  84.             MOVEQ    #sqHDSize,D0                ;allocate a slot queue element
  85.             _NewPtr    ,SYS,CLEAR                    ;get it from system heap cleared
  86.             BNE      OpError
  87.             MOVE.W    #SIQType,SQType(A0)            ;setup queue ID                        
  88.             MOVE.L    A4,SQAddr(A0)                ;setup int routine address
  89.             MOVE.L    dctlDevBase(A3),SQParm(A0)    ;save slot base addr as A3 parm
  90.             CLR.L    D0
  91.             MOVE.B    dctlSlot(A3),D0                ;setup slot #
  92.             _SIntInstall                        ;and do install
  93.             BNE.S    OpError
  94.  
  95. ; Save SQElPtr for removal.                                                            
  96.             MOVE.L    dCtlStorage(A3),A1            ;Get pointer to private storage.
  97.             MOVE.L    (A1),A1                        ;    
  98.             MOVE.L    A0,saveSQElPtr(A1)            ;Save the SQ element pointer.
  99.  
  100. ; Enable interrupts..
  101.             ADD.L    #ClrVInt,A0                    ;bump to interrupt reg
  102.             CLR.B    (A0)                        ;clear it.
  103.  
  104.             MOVEQ    #0,D0                        ;no error
  105.             BRA.S    EndOpen
  106.  
  107. ;  Error.
  108. OpError        MOVE.L    #OpenErr,D0                    ; say can't open driver.
  109.  
  110.  
  111. EndOpen        RTS                                 ;return
  112.             
  113. ; 
  114. ;-------------------------------------------------------------                                
  115. ;    The Interrupt handler for TFB board
  116. ;-------------------------------------------------------------
  117. ; The interrupt Handler
  118. ; On entry A1 contains the slot base address
  119. ; D0-D3/A0-A3 have been preserved.
  120. BeginIH        MOVE.L    A1,A0            ; get screen base
  121.             MOVE.L    A1,D0            ; and save for later
  122.             ADD.L    #ClrVInt,A0        ; get offset to register
  123.             CLR.B    (A0)            ; clear interrupt from card
  124.  
  125.                                     ; D0 = $Fssxxxxx
  126.             ROL.L    #8,D0            ; D0 <- $sxxxxxFs    Convert the address into 
  127.             AND        #$0F,D0            ; D0 <- $sxxx000s    the slot number.
  128.  
  129.             MOVE.L    JVBLTask,A0        ; call the VBL task manager
  130.             JSR        (A0)            ; with slot # in D0
  131.  
  132.             MOVEQ    #1,D0            ; signal that int was serviced                
  133.             RTS                        ; and return to caller
  134.  
  135.             
  136. ; 
  137. **********************************************************************
  138. *
  139. * VideoClose releases the device's private storage.
  140. *
  141. *
  142. * Entry:    A0 = param block pointer
  143. *            A1 = DCE pointer
  144. *
  145. * Locals:    A2 = Saved param block pointer
  146. *            A3 = Saved DCE pointer
  147. *            A4 = Temporary.
  148. *
  149. **********************************************************************
  150.  
  151. VideoClose    
  152.             MOVE.L    A0,A2                        ;A2 <- param block pointer            
  153.             MOVE.L    A1,A3                        ;A3 <- DCE pointer                    
  154.  
  155.             MOVE.L    dCtlDevBase(A3),A4            ;A4 <- base address of device.        
  156.             ADD.L    #DisableVInt,A4                ;Adjust the base                    
  157.             CLR.B    (A4)                        ;Disable interrupt from card        
  158.  
  159.             MOVE.L    dCtlStorage(A3),A0            ;Get pointer to private storage        
  160.             MOVE.L    (A0),A0                        ;                                    
  161.             MOVE.L    saveSQElPtr(A0),A0            ;Get the SQ element pointer.        
  162.             _SIntRemove                            ;Remove the interrupt handler.        
  163.             
  164.             MOVE.L    dCtlStorage(A3),A0            ;Get pointer to private storage        
  165.             MOVE.L    (A0),A0                        ;                                    
  166.             MOVE.L    GammaPtr(A0),A0                ;get pointer to gamma table
  167.             _DisposPtr                            ;and dispose it
  168.             
  169.             MOVE.L    dCtlStorage(A3),A0            ;Dispose of the private storage.    
  170.             _DisposHandle                        ;                                
  171.  
  172.  
  173.             MOVEQ    #0,D0                        ;get error into D0        
  174.             RTS                                 ;return to caller
  175.  
  176.  
  177. ; 
  178. **********************************************************************
  179. *
  180. * Video Driver Control Call Handler.  Right now there are six calls:
  181. *
  182. *    (0)  Reset (VAR mode, page: INTEGER; VAR BaseAddr: Ptr);
  183. *    (1)  KillIO
  184. *    (2)     SetMode(mode, page: INTEGER; VAR BaseAddr: Ptr);
  185. *
  186. *   Entry:     A0         = param block pointer
  187. *            A1         = DCE pointer
  188. *    Uses:    A2        = cs parameters (ie. A2 <- csParam(A0))  (must be preserved)
  189. *            A3         = scratch (doesn't need to be preserved)
  190. *            A4        = scratch (must be preserved)
  191. *            D0-D3     = scratch (don't need to be preserved)
  192. *
  193. *    Exit:    D0          = error code
  194. *
  195. **********************************************************************
  196.  
  197. ; Decode the call
  198. VideoCtl    MOVEM.L    A0/A4/D4,-(SP)                ; save work registers (A0 is saved because it is used by ExitDrvr).
  199.  
  200.             MOVE.W    csCode(A0),D0                ; get the opCode
  201.             MOVE.L    csParam(A0),A2                ; A2 <- Ptr to control parameters        
  202.  
  203.             CMP.W    #2,D0                        ;IF csCode NOT IN [0..6] THEN            
  204.             BHI.S    CtlBad                        ;  Error, csCode out of bounds.
  205.             LSL.W    #1,D0                        ;Adjust csCode to be an index into the table.
  206.             MOVE.W    CtlJumpTbl(PC,D0.W),D0        ;Get the relative offset to the routine.
  207.             JMP        CtlJumpTbl(PC,D0.W)            ;GOTO the proper routine.
  208.                 
  209. CtlJumpTbl    DC.W    VidReset-CtlJumpTbl            ;$00 => VidReset
  210.             DC.W    CtlGood-CtlJumpTbl            ;$01 => CtlGood
  211.             DC.W    SetVidMode-CtlJumpTbl        ;$02 => SetVidMode
  212.  
  213. CtlBad        MOVEQ    #controlErr,D0                ; else say we don't do this one
  214.             BRA.S    CtlDone                        ; and return
  215.             
  216. CtlGood        MOVEQ    #noErr,D0                    ; return no error
  217.  
  218. CtlDone        MOVEM.L    (SP)+,A0/A4/D4                ; restore registers.
  219.             BRA        ExitDrvr
  220.  
  221. ; 
  222. VidReset
  223. ;---------------------------------------------------------------------
  224. ;
  225. ;    Reset the card to its default (one bit per pixel)
  226. ;
  227. ;---------------------------------------------------------------------
  228.  
  229.             BSR        TFBInit                        ; initialize the card            
  230.             MOVE    #OneBitMode,csMode(A2)        ; return default mode            
  231.             MOVE    #1,D1                        ; get depth in D1                
  232.             MOVEQ    #0,D0                        ; get page in D0                
  233.             MOVE    D0,csPage(A2)                ; return the page                
  234.             MOVE.L    dCtlStorage(A1),A3            ; get handle to our data        
  235.             MOVE.L    (A3),A3                        ; A3 = our data                    
  236.             BSR        TFBSetDepth                    ; set the depth    from D1            
  237.             BSR        TFBSetPage                    ; set the page from D0            
  238.             MOVE.L    saveBaseAddr(A3),csBaseAddr(A2)    ; return the base address    
  239.             BSR        GrayScreen                    ; paint the screen gray            
  240.             BRA.S    CtlGood                        ; => no error                    
  241.  
  242. SetVidMode
  243. ;---------------------------------------------------------------------
  244. ;
  245. ;    Set the card to the specified mode and page.  
  246. ;     If either is invalid, returns badMode error.
  247. ;
  248. ;   If the card is already set to the specified mode, then do nothing.
  249. ;
  250. ;    Note: Mode set is [1,2,4,8].
  251. ;
  252. ;---------------------------------------------------------------------
  253.  
  254.             MOVE.W    csMode(A2),D1                ; D1 = mode
  255.             BSR        ChkMode                        ; get mode, check, map to depth (1, 2, 4 or 8) {D1 <- depth}
  256.             BNE.S    CtlBad                        ; => not a valid mode
  257.             
  258.             MOVE.W    csPage(A2),D0                ; D0 = page
  259.             BSR        ChkPage                        ; check page                    
  260.             BNE.S    CtlBad                        ; => not a valid page            
  261.  
  262. ; Only set the mode if it has changed
  263. ; TFBSetDepth and TFBSetPage update the saved data in the dCtlStorage
  264.  
  265. SetEm        MOVE.L    dCtlStorage(A1),A3            ; get handle to our data
  266.             MOVE.L    (A3),A3                        ; A3 = our data
  267.             MOVE.W    csMode(A2),D2                ; D2 = mode                        
  268.             CMP        saveMode(A3),D2                ; has the mode changed?            
  269.             BEQ.S    ModeOK1                        ; => no, check the page            
  270.             BSR        TFBSetDepth                    ; set the depth, get rowbytes    
  271.             BSR        TFBSetPage                    ; set the page                    
  272.             BRA.S    NoChange                    ; => and return
  273.             
  274. ModeOK1        BSR        TFBSetPage                    ; set the page                    
  275.             
  276. NoChange    MOVE.L    saveBaseAddr(A3),csBaseAddr(A2)    ; return the base address    
  277.             BRA.S    CtlGood                        ; => return no error
  278.  
  279. ; 
  280. **********************************************************************
  281. *
  282. * Video Driver Status Call Handler.  Right now there are three calls:
  283. *
  284. *    (0)  Error
  285. *    (1)  Error
  286. *    (2)     GetMode
  287. *    (3)  Error
  288. *    (4)     GetPage
  289. *    (5)     GetPageBase
  290. *
  291. *   Entry:     A0         = param block
  292. *            A1         = DCE pointer
  293. *    Uses:    A2        = cs parameters (ie. A2 <- csParam(A0))  (must be preserved)
  294. *            A3         = scratch (doesn't need to be preserved)
  295. *            D0-D3     = scratch (don't need to be preserved)
  296. *
  297. *    Exit:    D0          = error code
  298. *
  299. **********************************************************************
  300.  
  301. VideoStatus    MOVE.W    csCode(A0),D0                ; get the opCode
  302.             MOVE.L    csParam(A0),A2                ; A2 <- Ptr to control parameters    
  303.             
  304.  
  305.             CMP.W    #5,D0                        ;IF csCode NOT IN [0..6] THEN
  306.             BHI.S    StatBad                        ;  Error, csCode out of bounds.
  307.             LSL.W    #1,D0                        ;Adjust csCode to be an index into the table.
  308.             MOVE.W    StatJumpTbl(PC,D0.W),D0        ;Get the relative offset to the routine.
  309.             JMP        StatJumpTbl(PC,D0.W)        ;GOTO the proper routine.
  310.                 
  311. StatJumpTbl    DC.W    StatBad-StatJumpTbl            ;$00 => Error
  312.             DC.W    StatBad-StatJumpTbl            ;$01 => Error
  313.             DC.W    GetMode-StatJumpTbl            ;$02 => GetMode
  314.             DC.W    StatBad-StatJumpTbl            ;$03 => Error
  315.             DC.W    GetPage-StatJumpTbl            ;$04 => GetPage
  316.             DC.W    GetPageBase-StatJumpTbl        ;$05 => GetPageBase
  317.             
  318. StatBad        MOVEQ    #statusErr,D0                ; else say we don't do this one
  319.             BRA        ExitDrvr                    ; and return
  320.             
  321. StatGood    MOVEQ    #noErr,D0                    ; return no error
  322.             BRA        ExitDrvr
  323.  
  324.  
  325. GetMode
  326. ;---------------------------------------------------------------------
  327. ;
  328. ;    Return the current mode
  329. ;
  330. ;---------------------------------------------------------------------
  331.  
  332.             MOVE.L    dCtlStorage(A1),A3                ; get handle to our storage
  333.             MOVE.L    (A3),A3                            ; get pointer to our storage
  334.             MOVE.W    saveMode(A3),csMode(A2)            ; return the mode
  335.             MOVE.W    savePage(A3),csPage(A2)            ; return the page number
  336.             MOVE.L    saveBaseAddr(A3),csBaseAddr(A2)    ; and the base address
  337.             
  338.             BRA.S    StatGood                        ; => return no error
  339.             
  340.  
  341.             
  342. GetPage
  343. ;---------------------------------------------------------------------
  344. ;
  345. ;    Return the number of pages in the specified mode
  346. ;
  347. ;---------------------------------------------------------------------
  348.  
  349.             MOVE    csMode(A2),D1                ; get the mode                        
  350.             BSR        ChkMode                        ; check mode, get depth in D1        
  351.             BNE        StatBad                        ; => not a valid mode                
  352.  
  353.             MOVE.L    dCtlStorage(A1),A0            ; get private storage pointer    
  354.             TST.B    VRAM256K(A0)                ; 512K or 256K?                    
  355.             BNE.S    @1                            ; if TRUE, then 256K of RAM        
  356.             MOVEQ    #4,D0                        ; if FALSE, 512K vRAM (and 1 more page per mode)
  357.             BRA.S    @2
  358. @1            MOVEQ    #3,D0                        ; get one-bit page count            
  359. @2            DIVU    D1,D0                        ; divide by depth                    
  360.             ADD        #1,D0                        ; make it one based                    
  361.             MOVE    D0,csPage(A2)                ; return page count                    
  362.             BRA        StatGood                    ; => return no error                
  363.             
  364.             
  365.             
  366. ; 
  367. GetPageBase
  368. ;---------------------------------------------------------------------
  369. ;
  370. ;    Return the base address for the specified page in the current mode
  371. ;
  372. ;---------------------------------------------------------------------
  373.             
  374.             MOVE.L    dCtlStorage(A1),A3            ; get handle to our storage            
  375.             MOVE.L    (A3),A3                        ; get pointer to our storage        
  376.             MOVE    saveMode(A3),D1                ; get the current mode                
  377.             BSR        ChkMode                        ; convert to depth in D1            
  378.             MOVE.W    csPage(A2),D0                ; get the requested page            
  379.             BSR        ChkPage                        ; is the page valid?                
  380.             BNE        StatBad                        ; => no, just return                
  381.                         
  382.             MOVE    saveMode(A3),D1                ; get the current mode                
  383.             SUB        #OneBitMode,D1                ; make it 0 based                    
  384.             LEA        ModeTbl,A0                    ; point to tables                    
  385.             MULU    4(A0,D1*8),D0                ; calc page * rowBytes                
  386.             MULU    6(A0,D1*8),D0                ; calc page * rowBytes * height        
  387.             MOVEQ    #4,D1                        ; add offset for TFB                
  388.             ADD.L    D1,D0                        ; which doesn't use first long        
  389.             ADD.L    dCtlDevBase(A1),D0            ; add base address for card            
  390.             MOVE.L    D0,csBaseAddr(A2)            ; return the base address            
  391.             
  392.             BRA     StatGood                    ; => return no error
  393.             
  394.  
  395. ;---------------------------------------------------------------------
  396. ;
  397. ;    Exit from control or Status.
  398. ;
  399. ;---------------------------------------------------------------------
  400.  
  401. ExitDrvr    BTST    #NoQueueBit,ioTrap(A0)        ; no queue bit set?
  402.             BEQ.S    GoIODone                    ; => no, not immediate
  403.             RTS                                 ; otherwise, it was an immediate call
  404.  
  405. GoIODone    MOVE.L    JIODone,A0                    ; get the IODone address
  406.             JMP     (A0)                        ; invoke it
  407.  
  408.  
  409.  
  410.  
  411. **********************************************************************
  412. *
  413. *    Utilities (Hardware dependent)
  414. *
  415. **********************************************************************
  416.  
  417. TFBInit        RTS                                    ;Initialize the TFB
  418.  
  419. TFBSetDepth    RTS                                    ;Set the depth.
  420.  
  421. TFBSetPage    RTS                                    ;Set the page.
  422.  
  423. ChkMode        RTS                                    ;Check the current mode.
  424.  
  425. ChkPage        RTS                                    ;Check the current page.
  426.  
  427. GrayScreen    RTS                                    ;Gray the screen.
  428.  
  429. ModeTbl        DC.W    $AAAA,$AAAA,$0080,$01E0        ; one bit per pixel                    
  430.             DC.W    $CCCC,$CCCC,$0100,$01E0        ; two bit per pixel                    
  431.             DC.W    $F0F0,$F0F0,$0200,$01E0        ; four bit per pixel                
  432.             DC.W    $FF00,$FF00,$0400,$01E0        ; eight bit per pixel                
  433.             
  434.